Key Management Server (KMS)

Mit der Einführung von Windows Vista / Windows Server 2012 / Office 2010 hat Microsoft ein neues Volumen-Aktivierungs-Verfahren eingeführt. Für die Windows-Administratoren der Friedrich Alexander Universität bedeutet dies, dass keine Lizenz-Schlüssel mehr für Windows und Office Versionen zum Einsatz kommen.

Wichtige Informationen

Der KMS-Server ist nur aus dem Hochschul-LAN erreichbar!

Für den Betrieb von Windows ist eine direkte TCP/IP-Verbindung (Ethernet, kabelgebunden) zum KMS-Server im Uni-Netz notwendig.
Der KMS-Server ist via WLAN und VPN nicht erreichbar! Für Geräte ohne Ethernet-Schnittstelle müssen Sie einen entsprechenden Ethernet-Adapter (mit)beschaffen.

Dieser Dienst läuft auf dem KMS-Server des RRZE
kms.rrze.uni-erlangen.de
über den TCP-Port 1688.

IPv4-Netzbereiche freischalten lassen

Sie müssen die Ihnen zugeteilten IPv4-Netzbereiche bei der Software-Bestellung mit angeben, damit wir den KMS-Server freischalten. Änderungen und zusätzliche (private) (Sub)Netze müssen uns von der Kontaktperson der Einrichtung unter Angabe der Kundennummer an die Mailadresse software@fau.de mitgeteilt werden.

Windows Enterprise und Office Pro Plus aktivieren

Aktivierung für jeweils 180 Tage

Die Laufzeit beträgt nach jeder erfolgreichen Aktivierung jeweils 180 Tage.

Nicht bei jeder Verbindung zum FAU-LAN gelingt eine erneute Aktivierung.

Ist Ihr PC oft nur per WLAN verbunden, sollten Sie vor längeren Dienstreisen eine manuelle Aktivierung erzwingen. Nutzen Sie dazu bitte die unten aufgeführten Verfahren. Sie benötigen dazu keine Admin-Rechte. Sie können die Aktivierung auch bei Nutzung von KMS Autodiscovery nutzen.

Vollautomatische Konfiguration für Mitglieder der AD-Domäne FAUAD.FAU.DE

Mitglieder der AD-Domäne FAUAD finden den KMS-Eintrag automatisch über die AD-integrierten DNS-Dienste. Dabei spielt die Konfiguration des primären DNS-Suffixes keine Rolle.

Auf diesem Bild ist das Fenster der Windows Systemsteuerung mit den jeweiligen Einstellungen geöffnet.
KMS Autodiscovery am Beispiel von Windows 10

Konfiguration des Host-DNS-Suffixes (keine Mitglieder der AD-Domäne FAUAD.FAU.DE)

Alternativ zur AD-Variante kann der DNS-Suffix des Computers explizit auf uni-erlangen.de eingestellt werden. Der KMS-Dienst wird automatisch gefunden und kontaktiert.

Aktivierung per Batch-Datei

Sie können auf FAU-Rechnern folgende Batchdatei nutzen, die bei Verwendung des Standard-Installationsschemas von Microsoft alle Kombinationen von Microsoft Windows 7 / 8.1 / 10 Enterprise und Microsoft Office Pro Plus 2010 / 2013 / 2016 / 2019 aktiviert.

Die Datei muss initial mit Run As Administrator bzw. Ausführen als Administrator gestartet werden, wenn der KMS-Server fest eingetragen werden soll.

:: Speichern Sie diesen Text mit der Endung .bat ab:. Zum Beispiel
:: FAU-KMS-Win+MSO_v3.bat
:: Mit dieser Batchdatei können sie auf Ihrem FAU-Dienstrechner die an der FAU verwendeten
:: Volumenlizenzen von Microsoft Windows und Office aktivieren, wenn Sie sich im FAU-LAN befinden.
::
:: Regionales RechenZentrum Erlangen (RRZE)
:: Autor: Thomas Reinfelder, rrze-software@fau.de
:: Version 3 vom 19.11.2018

@ECHO Off
Echo MICROSOFT KMS-AKTIVIERUNG von Echo WINDOWS ENTERRISE / EDUCATION und Echo OFFICE PRO PLUS zur Nutzung auf Dienstrechner der FAU
Echo =====================================
Echo Bitte die Meldungen beachten ob die Aktivierung erfolgreich war.
Echo =====================================
Echo Mögliche Fehlerquellen
Echo ===
Echo Die Aktivierung ist nur aus dem LAN = Ethernet = KABEL (!!!!) der FAU möglich.
Echo --
Echo Falls Sie ein neues / weiteres Lehrstuhl-Netz (insbesondere private Netze!) erhalten haben, muss die Kontaktperson dies unter Angabe der KP-Kennung an software@fau.de melden damit wir den KMS-Server entsprechend freischalten.
Echo --
Echo Im Fehlerfall bitte Datum / Uhrzeit / Zeitzone / Sommer-/Winterzeit überprüfen
Echo --
Echo Falls die Aktivierung fehlschlägt bitte die Batchdatei einmalig via rechte Maustaste "Ausführen als Admin" / "Run as admin" starten.
Echo ===
Echo Um fortzufahren
pause


:: Auf erhöhten Rechten prüfen. Falls nicht, wird  nicht versucht den
:: KMS-Server einzutragen, da dies nur einen Fehler produzieren würde.
whoami /groups | find "S-1-16-12288" > nul 
if not errorlevel 1 goto WindowsKMSeintragen
goto WindowsAktivieren

:WindowsKMSeintragen
slmgr -skms kms.rrze.uni-erlangen.de
goto WindowsAktivieren

:WindowsAktivieren
slmgr -ato


:: In Office Pfad wechseln
:: Hier wird einfach nur stupide geprüft, in welchem Verzeichnis Office installiert ist... 
:: Funktioniert für Office 2010 / 2013 / 2016 / 2019 Pro Plus in 32/64bit unter Windows 32/64bit
::
:: Sofern vom Microsoft Standard abweichenden Installationspfade verwendet werden bitte anpassen
::
if exist "C:\Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" pushd "C:\Program Files (x86)\Microsoft Office\Office14\"
if exist "C:\Program Files (x86)\Microsoft Office\Office15\OSPP.VBS" pushd "C:\Program Files (x86)\Microsoft Office\Office15\"
if exist "C:\Program Files (x86)\Microsoft Office\Office16\OSPP.VBS" pushd "C:\Program Files (x86)\Microsoft Office\Office16\"
if exist "C:\Program Files\Microsoft Office\Office14\OSPP.VBS" pushd "C:\Program Files\Microsoft Office\Office14\"
if exist "C:\Program Files\Microsoft Office\Office15\OSPP.VBS" pushd "C:\Program Files\Microsoft Office\Office15\"
if exist "C:\Program Files\Microsoft Office\Office16\OSPP.VBS" pushd "C:\Program Files\Microsoft Office\Office16\"
:: KMS Server eintragen

:: Prüfen auf Admin-Rechte
whoami /groups | find "S-1-16-12288" > nul 
if not errorlevel 1 goto OfficeKMSeintragen
goto OfficeAktivieren

:OfficeKMSeintragen
cscript ospp.vbs /sethst:kms.rrze.uni-erlangen.de
goto OfficeAktivieren

:OfficeAktivieren
cscript ospp.vbs /act

pause

Manuelle Konfiguration

Windows und Office müssen separat aktiviert werden!

Aktivierung von Office Pro Plus per KMS
Aktivierung von Office Pro Plus per KMS
Aktivierung von Windows Enterprise per KMS
Aktivierung von Windows Enterprise per KMS

Windows Enterprise manuell aktivieren

  1. Eingabeaufforderung mit Run As Administrator bzw. Ausführen als Administrator starten
  2. slmgr -skms kms.rrze.uni-erlangen.de [Enter]
  3. Warten auf Ergebnisdialogbox
    „Der Schlüsselverwaltungsdienst-Computername wurde erfolgreich auf kms.rrze.uni-erlangen.de festgelegt“
  4.  slmgr -ato
  5. Im Erfolgsfall erscheint die Ergebnisdialogbox
    „Windows(R) …. wird aktiviert… Das Produkt wurde erfolgreich aktiviert.“

Microsoft Office Pro Plus manuell aktivieren

Installationspfad ermitteln

Allgemein:
 C:\Windows Programmordner\Microsoft Office\OfficeVersion

MSO 2013 in 32bit auf einem 64bit Windows:

C:\Program Files (x86)\Microsoft Office\Office15\

In diesem Verzeichnis muss die Datei „ospp.vbs“ vorhanden sein.

Windows Programmordner ermitteln
Windows 32bit Windows 64bit
Office 32bit C:\Program Files\ C:\Program Files (x86)\
Office 64bit C:\Program Files\

Microsoft Office 2010 = Office14
Microsoft Office 2013 = Office15
Microsoft Office 2016 = Office16

KMS Server eintragen & Aktvierung durchführen

  • Eingabeaufforderung mit Run As Administrator bzw. Ausführen als Administrator starten
  • Ins Office Verzeichnis wechseln
  • cscript ospp.vbs /sethst:kms.rrze.uni-erlangen.de [Enter]
  • cscript ospp.vbs /act [Enter]

Aktivierung erzwingen

  • Eingabeaufforderung starten
  • Ins Office Verzeichnis wechseln
  • cscript ospp.vbs /act [Enter]

Restlaufzeit der Aktivierung anzeigen

  • Eingabeaufforderung starten
  • Ins Office Verzeichnis wechseln
  • cscript ospp.vbs /dstatus [Enter]

„REMAINING GRACE: xxx days (yyy minute(s) before expiring).“

Fehlersuche

1. Haben Sie die von Ihnen genutzten IPv4 Netze der Software-Abteilung des RRZE gemeldet?

Sie müssen die Ihnen zugeteilten IPv4-Netzbereiche bei der Software-Bestellung mit angeben, damit wir den KMS-Server freischalten. Änderungen und zusätzliche (private) (Sub)Netze müssen uns von der Kontaktperson der Einrichtung unter Angabe der Kundennummer an die Mailadresse software@fau.de mitgeteilt werden.

2. Fehler-Code 0xC004F074

Vom Softwarelizenzierungsdienst wurde gemeldet, dass der Computer nicht aktiviert werden konnte. Der Schlüsselverwaltungsdienst (Key Management Service, KMS) ist nicht verfügbar.

Bitte prüfen sie

  • Datum
  • Uhrzeit
  • Sommer/Winterzeit
  • Zeitzone

des Rechners.

3. Übersicht weiterer Fehler-Codes nebst Lösungshinweisen

4. Allgemeine Erreichbarkeit des KMS-Servers prüfen

Start / Ausführen / CMD (Eingabeaufforderung)

telnet kms.rrze.uni-erlangen.de 1688

Der KMS sollte mit einer leerer Ausgabe antworten. Wird die Verbindung nicht aufgebaut oder sofort geschlossen, besteht ein Verbindungsproblem zum KMS-Server.

5. Manuelles Abfragen der KMS DNS-Info auf der Kommandozeile (mit fqdn)

C:\>nslookup -type=srv _vlmcs._tcp.fauad.fau.de
Server:  dns1.rrze.uni-erlangen.de
Address:  131.188.0.10

Non-authoritative answer:
_vlmcs._tcp.fauad.fau.de     SRV service location:
          priority       = 0
          weight         = 0
          port           = 1688
          svr hostname   = kms.rrze.uni-erlangen.de

fauad.fau.de            nameserver = faudc1.fauad.fau.de
fauad.fau.de            nameserver = faudc2.fauad.fau.de
kms.rrze.uni-erlangen.de        internet address = 131.188.13.36
faudc1.fauad.fau.de     internet address = 10.188.78.10
faudc2.fauad.fau.de     internet address = 10.188.78.11

Bekommt der Vista-Client keine entsprechende Antwort zurück, so ist entweder kein RRZE-Nameserver eingetragen oder der RRZE-Nameserver kann nicht erreicht werden.
überprüfen Sie Ihre IP- und DNS-Konfiguration.

6. Manuelles abfragen der KMS DNS-Info auf der Kommandozeile (mit rdn)

C:\>nslookup -type=srv _vlmcs._tcp
Server:  dns1.rrze.uni-erlangen.de
Address:  131.188.0.10

Non-authoritative answer:
_vlmcs._tcp.fauad.fau.de     SRV service location:
          priority       = 0
          weight         = 0
          port           = 1688
          svr hostname   = kms.rrze.uni-erlangen.de

fauad.fau.de            nameserver = faudc1.fauad.fau.de
fauad.fau.de            nameserver = faudc2.faauad.fau.de
kms.rrze.uni-erlangen.de        internet address = 131.188.13.36
faudc1.fauad.fau.de     internet address = 10.188.78.10
faudc2.fauad.fau.de     internet address = 10.188.78.11

Klappt der vorherige Test mit dem fqdn, dieser Test schlägt aber fehl, so müssen Sie noch die DNS-Such-Suffixe in der IP-Konfiguration korrigieren. uni-erlangen.de bzw. fau.de muss in der Suchliste enthalten sein.